asinfo.f

Go to the documentation of this file.

!      real depth, s, E0, sizex
!      integer code, id
!      do while (.true.)
!         write(0,*) ' enter code, E0'
!         E0=1.e8
!         code=2
!         read(*,*) code, E0
!         do id = 200, 1200, 100
!            depth = id
!            s= dep2s(E0, 1, depth)
!            write(*,*) depth, sizex(E0, 1, code, s)
!         enddo
!      enddo
!      end

      real function sizex(E0in, NN,  code, s)
      implicit none
      real E0in ! input primary total energy in GeV
      integer NN ! input. incident nucleon number 0--> photon, 1-->proton, 4-->He ...56-->Fe
      integer code ! input code
      real s ! input age

      real s2Ng, s2Ne, s2Nmu, s2Nh, E0, fac
      if(nn .ge. 1) then
         e0=e0in/nn
         fac=nn
      else
         e0=e0in
         fac =1
      endif
      if(e0 .gt. 1.e11 .or. e0 .lt. 1.e7) then
         write(0,*)
     *   "*******warning: E0/n=",e0, " is out of range ******"
      endif
         
      if(code .eq. 1) then
         sizex=s2ng(e0, s)
         if(nn .eq. 0) fac = 1.2
      elseif(code .eq. 2) then
         sizex=s2ne(e0, s)
         if(nn .eq. 0) fac = 1.2
      elseif(code .eq. 3) then
         sizex=s2nmu(e0, s)
         if(nn .eq. 0) fac = 0.01
      elseif(code .le. 6) then
         sizex=s2nh(e0, s)
         if(nn .eq. 0) fac = 0.01
      else
         write(0,*) ' code error=',code, ' to sizex'
         stop 6776
      endif
      sizex=sizex*fac
      end
!     ************************
      real function dep2cogdep(E0in, NN, dep)
!     ************************
      implicit none
      real E0in  ! input primary nucleus total energy in GeV.
      integer NN ! input incident nucleon number. 
      real dep ! input slant depth in g/cm^2

      real E0, eps
      eps = 3.e-3
      if(nn .eq. 0) then
         e0=e0in
      else
         e0=e0in/nn
      endif
!       function value is dep/cog. 
      if(abs(1.0- e0/1.e8) .lt. eps) then
         dep2cogdep=0.001442*dep
      elseif( abs(1.0-e0/1.e9) .lt. eps) then
         dep2cogdep=0.001247*dep
      elseif( abs(1.0-e0/1.e10) .lt. eps ) then
         dep2cogdep=0.001094*dep
      else
         dep2cogdep=(-7.556e-05*log(e0) + 0.002826999)* dep      
      endif
      end
!     ************************
      real function cogdep2nmu(E0, cogdep)
!     ************************
      implicit none
      real E0 ! input GeV
      real cogdep ! input dep/cog
      real a, b, c, d
      a=3.2e8 
      if(e0 .eq. 1e8) then
        b=4.8316
        c=5.9692 
        d=0.709
      elseif(e0 .eq. 1e9) then
         b=4.6796
         c=3.7835
         d=1.091
      elseif(e0 .eq. 1e10) then
         b=4.1251
         c=1.8791
         d=1.818
      else
         b = -0.1534*log(e0) + 7.7246
         c = -0.8881*log(e0) + 22.282
         d = 0.24081*log(e0) -3.7845
      endif   
      cogdep2nmu=a*cogdep**b * exp(-c*cogdep**d)
      end
!     ***********************
      real function cogdep2nh(E0, cogdep)
!     ***********************
      implicit none
      real E0 ! input GeV
      real cogdep ! input dep/cog
!
      real cogdep2Nmu
!        use mu at present
      cogdep2nh= cogdep2nmu(e0,cogdep)
      end
!     ***********************
      real function s2nh(E0, s)
!     ***********************
      implicit none
      real E0 ! input GeV
      real s  ! input age
!        use mu at present
      real s2Nmu
      s2nh = s2nmu(e0, s)
      end
!     ************************
      real function cogdep2ne(E0, cogdep)
!     ************************
      implicit none
      real E0 ! input GeV
      real cogdep ! input dep/cog
      real a, b, c, d
      real eps
      eps = 3.e-3

      a=1.e11
      if(abs(1.- 1e8/e0) .lt. eps ) then
         b=8.1044
         c=7.4068
         d=1.12022
      elseif( abs(1.- 1e9/e0) .lt.eps)  then
         b= 7.278 
         c= 5.063 
         d= 1.555
      elseif( abs(1.-1.e10/e0) .lt. eps) then
         b=6.3661
         c=2.7725
         d=2.2605
      else
         b =  -0.3774*log(e0) +  15.07
         c = -1.0063*log(e0) +  25.93
         d = 0.24760*log(e0) -3.48601
      endif   
      cogdep2ne=a*cogdep**b * exp(-c*cogdep**d)
      end
!     ************************
      real function cogdep2ng(E0, cogdep)
!     ************************
      implicit none
      real E0 ! input GeV
      real cogdep ! input dep/cog
      real a, b, c, d

      a=1.e12
      if(e0 .eq. 1e8) then
         b=8.00  
         c=8.034 
         d=0.941 
      elseif(e0 .eq. 1e9) then
         b=7.71  
         c=5.652 
         d=1.383
      elseif(e0 .eq. 1e10) then
         b= 6.91 
         c= 3.271 
         d= 2.022
      else
         b=-0.23669*log(e0)+12.445
         c=-1.03427*log(e0)+ 27.085
         d=0.2347*log(e0) -3.41583
      endif   
      cogdep2ng=a*cogdep**b * exp(-c*cogdep**d)
      end
!     ***************
      real function cogdep2s(E0,NN, cogdep)
!     ***************
!      for all energy      
      implicit none
      real E0   !  input not used now
      integer NN ! input incident nucleon number. not used now
      real cogdep ! input dep/cog
      cogdep2s = 10.28*cogdep**0.0407-9.228
      end
!     ***************
      real function dep2s(E0, NN, dep)
!     ***************
      implicit none 
      real E0  !input GeV
      integer NN ! input  incident nucleon number. not used now
      real dep ! input dep g/cm^2
      
      real dep2cogdep, cogdep2s
      dep2s=cogdep2s(e0,nn, dep2cogdep(e0,nn, dep))
      end
!     ***************
      real function s2ng(E0, s)
!     ***************
      implicit none 
      real E0  !input total incident energy/n  GeV
      real s ! input  age
      
      real cogdep2Ng, s2cogdep
      s2ng=cogdep2ng(e0,s2cogdep(e0,s))
      end
!     ***************
      real function s2ne(E0, s)
!     ***************
      implicit none 
      real E0  !input GeV
      real s    ! input age
      
      real s2cogdep, cogdep2Ne

      s2ne=cogdep2ne(e0, s2cogdep(e0, s))
      end
!     ***************
      real function s2nmu(E0, s)
!     ***************
      implicit none 
      real E0  !input GeV
      real s    ! input age
      
      real s2cogdep, cogdep2Nmu

      s2nmu=cogdep2nmu(e0,s2cogdep(e0, s))
      end
!     *************
      real function s2cogdep(E0, s)
!     *************
      real E0    ! not used now
      real s     ! input. age
      s2cogdep= ( (s+9.228)/10.28 )**(1./0.0407)
      end