cmuInte.f

Go to the documentation of this file.

      subroutine cmuinte
      implicit none
#include  "Ztrack.h"
#include  "Ztrackv.h"
#include  "Ztrackp.h"
#include  "Zcode.h"
      
      real*8 Et
      character*80 msg

      type(track)::aTrack, MoveSave
      save

      atrack=movedtrack

      if( intinfarray(processno)%process .eq. 'mupair' ) then
         call cmuprsmpe(movedtrack%p%fm%p(4),  et)
         atrack%p%fm%p(4) = atrack%p%fm%p(4) - et  ! muon; neglect angle
         call ce2p(atrack)
         nproduced = nproduced + 1
         pwork(nproduced) = atrack%p

         if(mupr .eq. 3 .or. eabsorb(1) .ne. 0 ) then
!              If Eabsorb(1)=0 and MuPr=2, Et will be missing
!              so we generate pair explicitly when Eabsorb(1)!=0
!              generate pair electrons; employ cpair
!              to do so, make aTrack a gamma of energy Et
            movesave = movedtrack
!               make MovedTrack to be a photon
            movedtrack%p%fm%p(4) = et
            call cmkptc(kphoton, kcasg, 0, movedtrack%p)
            call ce2p(movedtrack)
            call cpair
!             restore MovedTrack
            movedtrack = movesave
         endif
      elseif(intinfarray(processno)%process .eq.'mubrem' ) then   
         call cmubrsmpe(movedtrack%p%fm%p(4),  et)
         atrack%p%fm%p(4) = atrack%p%fm%p(4) - et  ! muon
         call ce2p(atrack)
         nproduced = nproduced + 1
         pwork(nproduced) = atrack%p   ! muon
         if(mubr .eq. 3 .or. eabsorb(1) .ne. 0 ) then
!             generate brems gamma; no deflection
            atrack%p%fm%p(4) = et
            call cmkptc(kphoton, kcasg, 0, atrack%p)
            call ce2p(atrack)
            nproduced = nproduced + 1
            pwork(nproduced) = atrack%p ! gamma
         endif
      elseif(intinfarray(processno)%process .eq.'munuci' ) then 
         call cmunsmpe(atrack%p%fm%p(4),  et)
         atrack%p%fm%p(4) = atrack%p%fm%p(4) - et ! muon
         call ce2p(atrack)
         nproduced = nproduced + 1
         pwork(nproduced) = atrack%p ! muon
         if(et .gt.  152.d-3 ) then
            if(  muni .eq. 3  .or. eabsorb(1) .ne. 0 )  then 
!             generate gamma-N interaction; employ gamma interaction
!             routine 
               movesave = movedtrack
               movedtrack%p%fm%p(4) = et
               call cmkptc(kphoton, 0, 0, movedtrack%p)
               call ce2p(movedtrack) ! adjust momentum
               call cfixmodel(movedtrack%p)  ! fix model since
                                             ! energy is < muon
               call cphotop 
!               restore muon
               movedtrack = movesave
            endif
         endif
      else
         write(msg, *) ' in cinteMuon: process=',
     *        intinfarray(processno)%process,
     *        ' undef. ProcessNo=',processno
         call cerrormsg(msg, 0)
      endif   
      end